Глава 10. Введение в объектно-ориентированное программирование

История развития программирования

В общих чертах ее можно представить диаграммой:

Машинное программирование

↓

Процедурное программирование

↓

Объектно-ориентированное программирование

Первый объектно-ориентированный язык программирования Симула был создан в 1967 г. и являлся расширением Алгола. В 1970 г. был разработан язык Смолток, но они не стали популярными из-за низкого быстродействия.

В современные прикладные языки объектно-ориентиро­ванное программирование пришло не сразу, так Турбо Паскаль и Си изначально не были объектно-ориентированными. В 1983 г. появилась объектно-ориентированная версия Си++, а в 1989 г. были включены средства работы с объектами в версию Турбо Паскаль 5.5.

Понятие объекта

Весь окружающий нас мир состоит из объектов, то есть предметов живой и неживой природы, которые представляются как единое целое, а отдельные их части образуют сложное взаимодействие друг с другом. Объект можно разделить на части, но тогда он перестает быть этим объектом.

Объекты являются высшим уровнем абстракции данных, так как отношения частей к целому и взаимоотношения между частями становятся понятнее и удобнее тогда, когда все содержится вместе как единое целое.

Обычно, классифицируя некоторый объект, возникают вопросы: чем этот объект похож на другие объекты из общего класса и чем он отличается от других. Каждый конкретный класс имеет свои особенности поведения и характеристик, определяющих этот класс. В свою очередь классы делятся на подклассы и т.д., то есть образуют иерархическую структуру, пример которой приведен на рис. 10.1.

Рис. 10.1. Пример фрагмента иерархии геометрических фигур

Наивысший уровень – самый общий, каждый последующий – более специфический, дополняемый деталями. На последнем уровне определяются цвет, стиль заполнения и т.п.

Более низкий уровень, называемый непосредственным потомком или подклассом, наследует данные (поля) и программы обработки (методы) уровня, стоящего выше. Уровень, стоящий выше подкласса, называют непосредственным предком или родителем. Объектный тип в Турбо Паскале может иметь не более одного родителя, но неограниченное число порожденных типов.

Иерархия объекта – это структурированный в виде дерева набор связей родитель-потомок набора объектов.

Основное правило ООП: если характеристика определена для какого-либо объекта, то все объекты, расположенные ниже данного определения, содержат эту характеристику.

Объектные типы в языке Турбо Паскаль очень похожи на комбинированный тип – записи, то есть объектный тип так же является составным, элементы, то есть поля которого могут иметь любой тип. Простейший пример объектного типа, – точка, – может выглядеть следующим образом.

Type

Point = object

X,Y: integer;

Visible: boolean

end;

Для формирования структуры типа объект используется служебное слово object. В дальнейшем тип Point можно использовать в программе обычным образом: определять переменные этого типа, как статически, в разделе Var, так и динамически, создавая экземпляр переменной этого типа с помощью процедуры New; работать с полями и прочее.

Но важнейшим и радикальным отличием от обычных комбинированных типов является возможность, наряду с полями, описывать в объектовом типе процедуры и функции, описывающие действия, которые можно выполнять с данным объектом. В этом и заключается одна из главных идей объектно-ориентированного подхода к программированию: предполагается, что объект содержит не только информацию о себе, но и правила своего поведения, оформленные в виде выполняемых фрагментов, – подпрограмм. Подпрограммы, определенные в объектном типе, называются методами объекта.

Свойства объектов

Любой язык объектно-ориентированного программирования характеризуется тремя основными свойствами.

1. Инкапсуляция – это определение записей с методами, то есть процедурами и функциями, работающими с полями этих записей, которое формирует новый тип данных – объект.

2. Наследование – определение объекта и дальнейшее использование всех его свойств для построения иерархии порожденных объектов с возможностью для каждого порожденного объекта, относящегося к иерархии, доступа методам и данным всех порождающих объектов.

3. Полиморфизм – присваивание определенному действию одного имени, которое затем совместно используется по всей иерархии объектов, причем каждый объект иерархии выполняет это действие характерным именно для него способом.

Технически инкапсуляция выполняется следующим образом. Непосредственно в описании типа задаются только заголовки подпрограмм-методов, а описания подпрограмм записываются отдельно, аналогично модулям. Имя, и соответственно обращение к методу, формируется аналогично обращению к полям записей: указывается имя объектного типа, а через точку-разделитель – имя подпрограммы-метода. Например, точка на экране может быть описана следующим образом:

Type

Point = object

X, Y: integer;

Visible: boolean;

Procedure Create (a, b: integer);

Procedure SwitchOn;

Procedure SwitchOff;

Procedure Move (dx, dy: integer);

Function GetX: integer;

Function GetY: integer;

End;

Procedure Point.Create (a, b: integer);

Begin

X := a; Y := b;

Visible := False;

End;

Procedure Point.SwitchOn;

Begin

Visible := True;

PytPixel (X, Y, GetColor);

End;

…

Function Point.GetX: integer;

Begin

GetX := X;

End;

…

Такое разделение диктуется, во-первых, необходимостью достижения большей наглядности определения объектов, во-вторых, становится возможным определение такого типа как интерфейсного элемента модуля. В этом случае реализация методов объекта будет размещена в соответствующем разделе.

Таким образом, объединение в одном имени информации о некотором реальном объекте (в примере – точке на экране монитора) и операциях над ним делает объектный тип замкнутым самодостаточным элементом, содержащим все требуемые знания о конкретном объекте. Имея такое описание, можно определять в программе экземпляры объектов, например:

Var

OnePoint: Point;

и в дальнейшем оперировать с этим экземпляром посредством его методов:

OnePoint.Create (100, 200);

OnePoint.SwitchOn;

OnePoint.Move (20, -10);

Для объектов, как и для записей, можно использовать оператор присоединения With, например:

With OnePoint do Begin

Create (100, 200);

SwitchOn;

Move (20, -10);

end;

Свойство наследования объектных типов позволяет при построении нового типа использовать ранее определенный объектный тип, что существенно экономит объем текста программы. Например, пусть необходимо построить объектный тип для круга на экране монитора. Структура информации для него очень похожа на структуру для точки: здесь также необходимы поля Х и Y для фиксации центра круга и логическое поле Visible для определения видимости круга в текущий момент. Кроме этого необходимо задавать радиус круга.

При традиционном процедурном стиле программирования можно или ввести для круга совершенно новую структуру, или сконструировать структуру, используя в ней поля ранее определенного типа, то есть сделать «структуру в структуре». Хотя оба подхода приемлемы, но объектно-ориентированное программирование предлагает иной, более предпочтительный подход.

В Турбо Паскале при определении типа потомка после служебного слова object должно быть указано имя родительского типа, например:

Type

Circle = object (Point)

Radius: integer

end;

Это означает, что в объектном типе Circle присутствует не только поле Radius, но неявно и все поля из типа Point, включая и методы:

Var

OneCircle: Circle;

Begin

…

OneCircle.Create (100, 200);

OneCircle.Radius := 30;

…

Тип-потомок может, в свою очередь, выступать как предок по отношению к другому объектному типу, например, определение фигуры «кольцо», состоящей из двух концентрических кругов:

Type

Ring = object (Circle)

Radius2: integer

end;

Здесь так же наследуются поля и методы типа Point, который считается косвенным предком для Ring. Длина такой цепочки не ограничена.

В примере с объектным типом Circle он имеет в своем составе методы объекта-предка Point. Но если методы получения координат центра GetX и GetY здесь можно использовать без изменений, то для рисования круга методы SwitchOn и SwitchOff неприменимы. Наиболее простым решением было бы ввести в новый тип и новые методы с новыми именами. Но объектно-ориентированный подход с использованием свойства полиморфизма позволяет определить новые методы со старыми именами, переопределив тем самым методы типа-родителя:

Type

Circle = object (Point)

Radius: integer;

Procedure Create (a,b,R: integer);

Procedure SwitchOn;

Procedure SwitchOff;

Procedure Move (dx,dy: integer);

Function GetR: integer;

end;

…

Procedure Circle.Create (a,b,R: integer);

Begin

Point.Create (a,b);

Radius := R

end;

…

Procedure Circle.SwitchOn;

Begin

Visible := True;

Graph.Circle (X,Y,Radius)

end;

…

Function Circle.GetR: integer;

Begin

GetR := Radius

end;

…

Так как стандартная процедура для рисования круга из модуля Graph так же имеет имя Circle, то для ее однозначной идентификации необходимо использовать составное имя Graph.Circle.

Это определение содержит следующие элементы:

1. Унаследованные поля X, Y, Visible;

2. Собственное поле Radius;

3. Унаследованные без изменения методы GetX, GetY;

4. Новый собственный метод GetR;

5. Полностью переопределенные методы Circle.SwitchOn, Circle.SwitchOff и Circle.Move;

6. Частично переопределенный метод Circle.Create. Для инициализации полей X, Y, Visible используется унаследованный метод Point.Create, но для инициализации поля Radius метод расширен.

Замечание 1. К полям любого объекта можно обращаться и напрямую, например, без использования процедуры Circle.Create, функции GetR и других. Но является правилом хорошего стиля программирования обращение ко всем полям только с помощью методов данного объекта, то есть поля считаются скрытыми.

Замечание 2. Переопределять можно только методы. Поля, указанные в родительском типе, наследуются безусловно и не могут быть переопределены, то есть имена полей типа-потомка не должны совпадать с именами полей типа-предка. Кроме того, переопределенный метод может иметь совершенно другие параметры в отличие от метода-предка.